Изменение характеристик техники

Всем привет , как поменять харктеристику техники в моде?

Меня заинтересовало изменение скорости и добавление звуков (pull up , rotor low и т.д.)от вертолета CH53 всем вертолетам

Собственно где хранятся харктеристики я нашел , но как их изменить без редактирования мода незнаю

 

Вот файл который мониторит состояние вертолета CH53, как его можно подключить в миссии для всех вертолетов?

_vehicle = _this select 0;
_maxspeed = 300;
_initheight = 2;
_wait = 0.5;

//Initiate Warning Flags
	_CritHydraulics = false;
	_CritEngine = false;
	_WarnCollision = false;
	_WarnDamage = false;
	_WarnEngine = false;
	_WarnFuelPres = false;
	_WarnFuel = false;
	_WarnSink = false;
	_CautRamp = false;
	_CautFuel = false;

//Initiate Variables
	_fuel = 0;
	_fuelLow = 0.5;
	_fuelCrit = 0.1;
	_resultfuel = 0;

_EHMissile = _vehicle addEventHandler ["IncomingMissile", {_vehicle vehicleRadio "dws_critical_incomingmissile";}];
//_EHEngine = _vehicle addEventHandler ["Engine", {if (!(_this select 1)) then {_vehicle vehicleRadio "dws_warning_engineout";};}];
//_EHGear = _vehicle addEventHandler ["Gear", {if (_this select 1) then {sleep 2;_vehicle vehicleRadio "dws_info_geardown";} else {sleep 2;_vehicle vehicleRadio "dws_info_gearup";};}];

while {(player in (crew _vehicle)) && (alive _vehicle)} do {
//while {(alive _vehicle)} do {
	_driver = driver _vehicle;
	_speed = speed _vehicle;
	_alt = (getPosASL _vehicle) select 2;
	_Ralt = (getPos _vehicle) select 2;
	_fuel = fuel _vehicle;
	sleep _wait;
	_resultfuel = _fuel - (fuel _vehicle);
	_resultalt = _alt - ((getPosASL _vehicle) select 2);
	_resultRalt = _Ralt - ((getPos _vehicle) select 2);
	
	_hydraulicsFailT = _vehicle getVariable "HydraulicsFailure";
	_engineFailT = _vehicle getVariable "EngineFailure";
	_rotorFailT = _vehicle getVariable "RotorFailure";
	_avionicsFailT = _vehicle getVariable "AvionicsFailure";
	
	//hintsilent format ["aaa %1",(fuel _vehicle )];
	
	// WARNING // LOOP // Aircraft is rapidly approaching nearby terrain
	if((_resultRalt > (6 * _wait)) && !(_WarnSink) && (_Ralt < 30) && !(_WarnCollision)) then {
		_vehicle vehicleRadio "dws_critical_pullup";
		sleep (1.4 - _wait);
	};
	
	// CRITICAL // LOOP // Hydraulics Failure
	if((_hydraulicsFailT) && !(_CritHydraulics)) then {
		_vehicle vehicleRadio "dws_critical_hydraulicsfailure";
		sleep (4 - _wait);
	};
	
	// CRITICAL // LOOP // Engine Failure
	if((_engineFailT) && !(_CritEngine)) then {
		_vehicle vehicleRadio "dws_critical_enginefailure";
		sleep (4 - _wait);
	};
	
	// WARNING // SINGLE // Damage Critical	
	if((damage _vehicle > 0.9) && !(_WarnDamage)) then {
		_vehicle vehicleRadio "dws_warning_damagecritical";
		sleep (4 - _wait);
	};
	
	// WARNING // LOOP // Loosing Fuel
	if((_resultfuel > (0.015 * _wait)) && !(_WarnFuelPres)) then {
		_vehicle vehicleRadio "dws_warning_fuelpressure";
		sleep 5;
	};
	
	// WARNING // LOOP // Aircraft is sinking too quickly
	if((((_resultalt > (2 * _wait)) && (!isEngineOn _vehicle))||((_resultalt > (15 * _wait)) && (isEngineOn _vehicle))) && !(_WarnSink)) then {
		_vehicle vehicleRadio "dws_warning_sinkrate";
		sleep 5;
	};
	
	// WARNING // SINGLE // Fuel Critical
	if(( fuel _vehicle < _fuelCrit) && !(_WarnFuel)) then {
		_vehicle vehicleRadio "dws_warning_fuelcritical";
		_WarnFuel = true;
		_CautFuel = true;
		sleep 5;
	};
	
	// CAUTION // LOOP // Aircraft is going too fast
	if((_speed > _maxspeed) && !(_WarnSink)) then {
		_vehicle vehicleRadio "dws_caution_overspeed";
		sleep 5;
	};
	
	// CAUTION // SINGLE // Ramp Open
	if((_vehicle animationPhase "ramp_bottom" > 0) && !(_CautRamp) && (_Ralt > 50)) then {
		_vehicle vehicleRadio "dws_caution_rampopen";
		_CautRamp = true;
		sleep 5;
	};
	
	// CAUTION // SINGLE // Fuel Low
	if(( fuel _vehicle < _fuelLow) && !(_CautFuel)) then {
		_vehicle vehicleRadio "dws_caution_fuelow";
		_CautFuel = true;
		sleep 5;
	};
	
	// ************ RESET VARIABLES *************
	
	if((_alt < 50) && (_CautRamp)) then {
		_CautRamp = false;
	};
	
	if((fuel _vehicle > _fuelCrit) && (_WarnFuel)) then {
		_WarnFuel = false;
	};
	
	if((fuel _vehicle > _fuelLow) && (_CautFuel)) then {
		_WarnFuel = false;
	};
	
};

_vehicle removeAllEventHandlers "IncomingMissile";
_vehicle removeAllEventHandlers "Engine";
_vehicle removeAllEventHandlers "Gear";

Изменено 28 октября 2015 пользователем Alex60 (история изменений)

закиньте в миссию и подключите его там (подсказка - compiles.sqf)