Установка замка на транспорт

Основной для скрипта послужил отрывок кода из этой темы. В первоначальном виде этот код отказался работать и было принято решение привести все в работоспособное состояние.

Прежде чем опубликовать этот скрипт, был произведен поиск по форуму на наличие подобных тем. По результатам нашлась другая тема, в которой упоминались возможные дюпы игроками при таких манипуляциях с транспортом. 

Чтобы исправить это, в скрипт был добавлен антидюп от JustBullet (с предварительного согласия автора). 

 

Для установки скрипта потребуется кастомный файл fn_selfActions.sqf и variables.sqf

 

1. Открыть файл fn_selfActions.sqf

 

2. В строке private добавить:

private ["_isVehicleCombo"]; //добавить

3. Найти строку: 

_isAlive = alive _cursorTarget;

и ниже нее вставить:

_isVehicleCombo = _typeOfCursorTarget in ["SUV_Camo","SUV_TK_CIV_EP1","ArmoredSUV_PMC_DZE"]; //перечисление классов

4. Найти строки:

    // logic vars
    _player_cook = false;
    _player_boil = false;

и выше них вставить: 

    if ((_isVehicleCombo) && (!locked _cursorTarget) && (!_inVehicle) && (player distance _cursorTarget < 5) && (_canDo) && (_ownerID == "0")) then {
    if (s_player_makeVehKey < 0) then {
        s_player_makeVehKey = player addaction [("<t color=""#FF0000"">" + ("Установить замок") +"</t>"),"custom\player_makeVehKey.sqf",_cursorTarget,-10,false,true,"",""];
        };
    } else {
        player removeAction s_player_makeVehKey;
        s_player_makeVehKey = -1;
    };

5. Найти строки:

    player removeAction s_player_studybody;
    s_player_studybody = -1;

и ниже вставить: 

    player removeAction s_player_makeVehKey;
    s_player_makeVehKey = -1;

6. Открыть файл variables.sqf и найти строку:

    s_player_studybody =     -1;

и после нее вставить:

    s_player_makeVehKey = -1;

 

7. Поместить в директорию custom файл с именем player_makeVehKey.sqf и следующим содержанием:

private ["_vehicle","_keyColor","_keyNumber","_keySelected","_isKeyOK","_config","_isOk","_isDamaged","_isOpen","_countplayers","_itemToolbox","_itemKeyKit","_itemCombo","_itemTin","_vehname","_hitpoints"];
_vehicle = _this select 3;
_isDamaged = false;
_isOpen = _vehicle getVariable ["CharacterID","0"];
_countplayers = count nearestObjects [player, ["CAManBase"], 12];
_itemToolbox =    "ItemToolbox" in items player;
_itemKeyKit =    "ItemKeyKit" in items player;
_itemCombo =    {_x == "ItemComboLock"} count magazines player;
_itemTin =        {_x == "ItemTinBar"} count magazines player;

_hitpoints = _vehicle call vehicle_getHitpoints;
{
    if ( ([_vehicle,_x] call object_getHit) > 0) then 
    {
        _isDamaged = true;
    };
} forEach _hitpoints;

if (_countplayers > 1) exitWith {systemchat "Анти-Дюп : Вы не можете выполнить это действие, если рядом с Вами игрок или зомби!"; DZE_ActionInProgress = false;}; //by JustBullet

if (!_itemToolbox) exitWith { cutText ["Для установки замка нужен Набор инструментов!" , "PLAIN DOWN"]; };

if (!_itemKeyKit) exitWith { cutText ["Для установки замка нужен Набор для создания ключей!" , "PLAIN DOWN"]; };

if (DZE_ActionInProgress) exitWith { cutText ["Установка уже выполняется!" , "PLAIN DOWN"]; };

if (_isDamaged) exitWith
{
    _vehname = getText (configFile >> "CfgVehicles" >> (typeof _vehicle) >> "displayName");
    cutText [format["Вы должны отремонтировать %1 перед установкой замка",_vehname], "PLAIN DOWN"];
};

if ((_itemCombo >= 1) && (_itemTin >= 1)) then 
{
    if (_isOpen == "0") then
    {
        DZE_ActionInProgress = true;
        player removeAction s_player_makeVehKey;
        player playActionNow "Medic";
        _vehicle setVehicleLock "LOCKED";
        PVDZE_veh_Lock = [_vehicle,true];
        publicVariable "PVDZE_veh_Lock";
        sleep 4;

        _keyColor = ["Green","Red","Blue","Yellow","Black"] call BIS_fnc_selectRandom;
        _keyNumber = (floor(random 2500)) + 1;
        _keySelected = format[("ItemKey%1%2"),_keyColor,_keyNumber];
        _isKeyOK = isClass(configFile >> "CfgWeapons" >> _keySelected);
        _config = _keySelected;
        _isOk = [player,_config] call BIS_fnc_invAdd;
        _characterID = str(getNumber(configFile >> "CfgWeapons" >> _keySelected >> "keyid"));


        waitUntil {!isNil "_isOk"};


        if (_isOk and _isKeyOK) then
        {
            PVDZE_veh_Upgrade = [_vehicle,[(getDir _vehicle),(getposATL _vehicle)],(typeOf _vehicle),true,_characterID,player];
            publicVariableServer "PVDZE_veh_Upgrade";
            player removeMagazine "ItemComboLock";
            player removeMagazine "ItemTinBar";
            _vehicle setVehicleLock "LOCKED";
            PVDZE_veh_Lock = [_vehicle,true];
            publicVariable "PVDZE_veh_Lock";
            DZE_ActionInProgress = false;
            _vehname = getText (configFile >> "CfgVehicles" >> (typeof _vehicle) >> "displayName");
            cutText [format["Вы установили замок на %1 \n Пожалуйста, подождите пока сервер обновит транспорт в базе данных...",_vehname], "PLAIN DOWN"];
        } 
        else 
        {
            _vehicle setVehicleLock "UNLOCKED";
            PVDZE_veh_Lock = [_vehicle,false];
            publicVariable "PVDZE_veh_Lock";
            _vehname = getText (configFile >> "CfgVehicles" >> (typeof _vehicle) >> "displayName");
            cutText [format["Вам не удалось установить замок на %1... \n Проверьте свободное место в снаряжении для ключа.",_vehname], "PLAIN DOWN"];
            DZE_ActionInProgress = false;
        };
    }
    else 
    {
        _vehname = getText (configFile >> "CfgVehicles" >> (typeof _vehicle) >> "displayName");
        cutText [format["На %1 уже установлен замок",_vehname], "PLAIN DOWN"];
        DZE_ActionInProgress = false;
    };
}
else 
{
    _vehname = getText (configFile >> "CfgVehicles" >> (typeof _vehicle) >> "displayName");
    cutText [format["Для установки замка на %1 требуется Combination Lock и Tin Bar.",_vehname], "PLAIN DOWN"];
    DZE_ActionInProgress = false;
};

! Скрипт обновлен !

 

На этом установка скрипта завершена. Для владельцев infistar необходимо добавить "s_player_makeVehKey" в _dayzActions = [];

 

Список транспорта, на который можно установить замок, определяется в _isVehicleCombo = _typeOfCursorTarget in ["classname","classname","classname"]; , где classname - имя класса транспорта. Можно добавить как конкретные классы, так и супер-классы, посмотреть полный список можно здесь.

Изменено 8 февраля 2016 пользователем Ramond (история изменений)

Все сделано добротно и качественно. Спасибо за скрипт. Работает идеально.

Проверено на Epoch 1.0.5.1 и Origins 1.8.x

Изменено 23 января 2016 пользователем Drupas (история изменений)

Что такое супер-классы? Добавил ли кто уже большую часть технику? 

Что такое супер-классы? Добавил ли кто уже большую часть технику? 

 

Суперклассы смотри здесь, чтобы совместить их с определенными классами транспорта, замени строку перечисления на эту: 

_isVehicleCombo = (_cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname");

И вписывай в нее, примерно так:

_isVehicleCombo = (_cursorTarget isKindOf "LandRover_Base" || _cursorTarget isKindOf "SUV_Base_EP1" || _cursorTarget isKindOf "ArmoredSUV_Base_PMC" || _cursorTarget isKindOf "HMMWV_Base" || _cursorTarget isKindOf "Kamaz_Base" || _cursorTarget isKindOf "Ural_Base" || _cursorTarget isKindOf "MTVR_base" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "BRDM2_HQ_TK_GUE_EP1");

 

Для включения всех классов транспорта: 

_isVehicleCombo = (_cursorTarget isKindOf "LandVehicle" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "Ship" || _cursorTarget isKindOf "Tank");

 

Суперклассы смотри здесь, чтобы совместить их с определенными классами транспорта, замени строку перечисления на эту: 

_isVehicleCombo = (_cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname");

И вписывай в нее, примерно так:

_isVehicleCombo = (_cursorTarget isKindOf "LandRover_Base" || _cursorTarget isKindOf "SUV_Base_EP1" || _cursorTarget isKindOf "ArmoredSUV_Base_PMC" || _cursorTarget isKindOf "HMMWV_Base" || _cursorTarget isKindOf "Kamaz_Base" || _cursorTarget isKindOf "Ural_Base" || _cursorTarget isKindOf "MTVR_base" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "BRDM2_HQ_TK_GUE_EP1");

 

Для включения всех классов транспорта: 

_isVehicleCombo = (_cursorTarget isKindOf "LandVehicle" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "Ship" || _cursorTarget isKindOf "Tank");

Благодарю

 

Суперклассы смотри здесь, чтобы совместить их с определенными классами транспорта, замени строку перечисления на эту: 

_isVehicleCombo = (_cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname" || _cursorTarget isKindOf "classname");

И вписывай в нее, примерно так:

_isVehicleCombo = (_cursorTarget isKindOf "LandRover_Base" || _cursorTarget isKindOf "SUV_Base_EP1" || _cursorTarget isKindOf "ArmoredSUV_Base_PMC" || _cursorTarget isKindOf "HMMWV_Base" || _cursorTarget isKindOf "Kamaz_Base" || _cursorTarget isKindOf "Ural_Base" || _cursorTarget isKindOf "MTVR_base" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "BRDM2_HQ_TK_GUE_EP1");

 

Для включения всех классов транспорта: 

_isVehicleCombo = (_cursorTarget isKindOf "LandVehicle" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "Ship" || _cursorTarget isKindOf "Tank");

isKindOf "AllVehicles";

Меню появляется и тут же пропадает, в инфистар  добавил "s_player_makeVehKey". . В чем еще может быть проблема ?.

Щас вообще перестала появляться ((( хотя ни чего не менял

Изменено 13 марта 2016 пользователем Lexa008 (история изменений)

Клёвая штука. Автор респект.

От себя добавлю файл player_makeVehKey.sqf сохранить в кодировке UTF-8 без ВОМ, иначе не пишет какие предметы нужны.

Меню появляется и тут же пропадает, в инфистар  добавил "s_player_makeVehKey". . В чем еще может быть проблема ?.

Щас вообще перестала появляться ((( хотя ни чего не менял

Автору +. Разобрался в чем дело..Все заработало.

Спасибо

isKindOf "AllVehicles";

 

Подскажи пожалуйста... Все работает, но почему-то остается куча меню "Установить замок". Что я сделал не так?

 

 

Обновлено, разобрался. Нужно просто внимательнее следовать гайду. Спасибо. =)

Изменено 25 мая 2016 пользователем NickPS (история изменений)

isKindOf "AllVehicles";

Тогда добавляет "Установить замок" даже на трупы. =))

Так что:

_isVehicleCombo = (_cursorTarget isKindOf "LandVehicle" || _cursorTarget isKindOf "Air" || _cursorTarget isKindOf "Ship" || _cursorTarget isKindOf "Tank");